Wednesday, 12 September 2012

Analyse license types [AX 2012]

I wanted to do a quick analysis on the license types in AX and how the menu items affect them (by count). This is extremely useful when you are creating new roles too.

I created a pivot table displaying the Roles on the Row, the License types on the Column and the Count of the Entry points (Menu items) as the value. This allows you to drill into the counts and find which menu items have make up a license type.

PivotTable2012-08-27_1556

Below is a quick job to export a csv file. Which can be opened up in excel to create the same pivot table.

static void checkLicenseTypeByRoleEntryPoint(Args _args)
{
    SysSecRoleEntryPointsTmp    srepTbl;
    SysUserLicenseMetadataTmp   slsaTmp;
    SecurityRole                securityRole;
    CommaTextIo                 commaTextIo;
    FileIOPermission            permission;
    MenuFunction                menuFunction;
    str                         menuLabel;
    str                         fileName = @"C:LicenseTypeByRoleEntryPoint.csv";
    FromTime                    startTime = timeNow();
    #File
 
    delete_from srepTbl;
    delete_from slsaTmp;
 
    SysUserLicenseMiner::BuildLicenseMetadataTable(slsaTmp);
    SysUserLicenseMiner::BuildRoleToUserTypeInfo(slsaTmp, srepTbl);
 
    permission = new FileIOPermission(fileName,#io_write);
    permission.assert();
    commaTextIo = new CommaTextIo(fileName,#io_write);
 
    //Header
    commaTextIo.write(
        "Entry type",
        "Entry point AOT name",
        "Entry point label",
        "Role AOT name",
        "Role name",
        "License type");
 
    while select srepTbl
        join securityRole
        where securityRole.RecId == srepTbl.RoleRecId
    {
        menuFunction    = null;
        menuLabel       = '';
        switch (srepTbl.EntryPointType)
        {
            case EntryPointType::MenuItemAction:
                menuFunction = new MenuFunction(srepTbl.EntryPointName, MenuItemType::Action);
                break;
 
            case EntryPointType::MenuItemDisplay:
                menuFunction = new MenuFunction(srepTbl.EntryPointName, MenuItemType::Display);
                break;
 
            case EntryPointType::MenuItemOutput:
                menuFunction = new MenuFunction(srepTbl.EntryPointName, MenuItemType::Output);
                break;
        }
 
        if (menuFunction)
        {
            menuLabel = menuFunction.label();
        }
 
        commaTextIo.write(
            strFmt("%1",srepTbl.EntryPointType),
            srepTbl.EntryPointName,
            menuLabel,
            srepTbl.RoleAotName,
            SysLabel::labelId2String(securityRole.Name),
            strFmt("%1",srepTbl.UserLicType));
    }
    CodeAccessPermission::revertAssert();
 
    info(strFmt("Total time: %1", timeConsumed(startTime, timeNow())));
}
 

Note: Way back in March I did a write up on the security development tool that was released for AX2012. This is a very helpful too and we should make good use of it.

http://dynamicsnavax.blogspot.com/2012/03/security-development-tool-ax-2012.html

Click on the link to open a sample excel file with the base AX license detail. (Make sure to download the file and open with excel)

You can download the zipped excel file. I have extracted this of an AX 2012 CU2 environment.

https://docs.google.com/open?id=0B1mVzLORe7KKTEgxZmRZcncwN0E

3 comments:

Mark Davies said...

Thanks this has been very useful!!

Note that there was one minor issue with generating the output file which we resolved by inserting the "\\" as shown below;

str fileName = @"C:\\LicenseTypeByRoleEntryPoint.csv";

Иван Иванов said...

Hi it's a great code and it helped me a lot, but I am realy new to Dynamics an I need some help. I need something like that but with duties and privileges included. Something like SysSecFlatData table but with user license cal. Or when you get to AOT->security->roles->right click on some role->Add Ins->security tools-> view related security objects. This list is perfect for me it contains the user license cal along with other data.

Munib Ahmed said...

Hey
I haven't done anything more than that. I think the whole security reporting is a little lacking. Consider using the security dev tool.