Skip to main content

Analyse license types [AX 2012]

I wanted to do a quick analysis on the license types in AX and how the menu items affect them (by count). This is extremely useful when you are creating new roles too.
I created a pivot table displaying the Roles on the Row, the License types on the Column and the Count of the Entry points (Menu items) as the value. This allows you to drill into the counts and find which menu items have make up a license type.
PivotTable2012-08-27_1556
Below is a quick job to export a csv file. Which can be opened up in excel to create the same pivot table.
static void checkLicenseTypeByRoleEntryPoint(Args _args)
{
    SysSecRoleEntryPointsTmp    srepTbl;
    SysUserLicenseMetadataTmp   slsaTmp;
    SecurityRole                securityRole;
    CommaTextIo                 commaTextIo;
    FileIOPermission            permission;
    MenuFunction                menuFunction;
    str                         menuLabel;
    str                         fileName = @"C:\LicenseTypeByRoleEntryPoint.csv";
    FromTime                    startTime = timeNow();
    #File

    delete_from srepTbl;
    delete_from slsaTmp;

    SysUserLicenseMiner::BuildLicenseMetadataTable(slsaTmp);
    SysUserLicenseMiner::BuildRoleToUserTypeInfo(slsaTmp, srepTbl);

    permission = new FileIOPermission(fileName,#io_write);
    permission.assert();
    commaTextIo = new CommaTextIo(fileName,#io_write);

    //Header
    commaTextIo.write(
        "Entry type",
        "Entry point AOT name",
        "Entry point label",
        "Role AOT name",
        "Role name",
        "License type");

    while select srepTbl
        join securityRole
        where securityRole.RecId == srepTbl.RoleRecId
    {
        menuFunction    = null;
        menuLabel       = '';
        switch (srepTbl.EntryPointType)
        {
            case EntryPointType::MenuItemAction:
                menuFunction = new MenuFunction(srepTbl.EntryPointName, MenuItemType::Action);
                break;

            case EntryPointType::MenuItemDisplay:
                menuFunction = new MenuFunction(srepTbl.EntryPointName, MenuItemType::Display);
                break;

            case EntryPointType::MenuItemOutput:
                menuFunction = new MenuFunction(srepTbl.EntryPointName, MenuItemType::Output);
                break;
        }

        if (menuFunction)
        {
            menuLabel = menuFunction.label();
        }

        commaTextIo.write(
            strFmt("%1",srepTbl.EntryPointType),
            srepTbl.EntryPointName,
            menuLabel,
            srepTbl.RoleAotName,
            SysLabel::labelId2String(securityRole.Name),
            strFmt("%1",srepTbl.UserLicType));
    }
    CodeAccessPermission::revertAssert();

    info(strFmt("Total time: %1", timeConsumed(startTime, timeNow())));
}
 
Note: Way back in March I did a write up on the security development tool that was released for AX2012. This is a very helpful too and we should make good use of it.
http://dynamicsnavax.blogspot.com/2012/03/security-development-tool-ax-2012.html
Click on the link to open a sample excel file with the base AX license detail. (Make sure to download the file and open with excel)
You can download the zipped excel file. I have extracted this of an AX 2012 CU2 environment.
https://docs.google.com/open?id=0B1mVzLORe7KKTEgxZmRZcncwN0E
Labels:

Popular posts from this blog

Approve Workflow via email using template placeholders #Dyn365FO

Dynamics 365 for Finance and Operations has placeholders which can be inserted into the instructions. Normally you would want this to show up in the email that is sent. One of the most useful ones is the URL link to the exact record that you are approving. In the workflow configurations use the placeholder and build up your message. Towards the end it has workflow specific ones. The URL token is %Workflow.Link to web% . For the technical people the token is replaced in this class WorkflowDocumentField. This is what I inserted into my email template. <BODY> subject: %subject% <BR> message: %message% <BR> company: %company% <BR> for: %for% <BR> </BODY> Should look like this. The final result looks like this. If you debug these are the place holders that are put together.
Read more

AX - How to use Set and SetEnumerator

The Set class is used for the storage and retrieval of data from a collection in which the values of the elements contained are unique and serve as the key values according to which the data is automatically ordered. You can create a set of primitive data types or complex data types such as a Class, Record or Container. Below is sample of a set of records. static void _Set(Args _args) {     CustTable       custTable;     Set             set = new Set(Types::Record);     SetEnumerator   setEnumerator;     ;     while select custTable     {         if (custTable && !set.in(custTable))         {             set.add(custTable);         }     }     if (!set.empty())     {    ...
Read more

Purchase requisition – Price

The price fields on the purchase requisition are non-editable for catalogue items. It is expected that a trade agreement be created. The price fields are only editable for these conditions: Form is opened view AP -> Periodic -> Purchase Requisition -> All purchase requisition, or Line type is “Non-catalogue item”, or User is task owner. Ie. The task is assigned to the user. In other words he/she maybe the purchaser that gets the price. User is approval owner. Ie. The approval is assigned to the user. In other words he/she maybe the manager that approves the final requisition. For catalogue items on the purchase requisition line can only select between the vendor directly associated with the item and the cheapest vendor as found through the purchase price trade agreements. If another vendor is requested the vendor can be blanked and the user can enter a “Proposed vendor” in the proposed vendor field on the general tab page for the purchase requisition line.   NOTE: ...
Read more